Lyrik.ebnf_alternative 1.11 KB
Newer Older
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
@ whitespace = horizontal
@ drop = whitespace

gedicht           = bibliographisches { LEERZEILE }+ [serie] §titel text /\s*/ ENDE

bibliographisches = autor §"," [NZ~] werk "," [NZ~] ort "," [NZ~] jahr "."
autor             = namenfolge [verknüpfung]
werk              = wortfolge ["." §untertitel] [verknüpfung]
untertitel        = wortfolge [verknüpfung]
ort               = wortfolge [verknüpfung]
jahr              = JAHRESZAHL ~

wortfolge         = { WORT [L] }+
namenfolge        = { NAME [L] }+
verknüpfung       = "<" ziel ">"
ziel              = ZEICHENFOLGE ~

serie             = !(titel vers NZ vers) { NZ zeile }+ { LEERZEILE }+

titel             = { NZ [L] zeile { LEERZEILE }+ }+
zeile             = { ZEICHENFOLGE [L] }+

text              = { strophe {LEERZEILE} }+
strophe           = { NZ vers }+
vers              = { ZEICHENFOLGE [L] }+

WORT              = /\w+/
NAME              = /\w+\.?/
ZEICHENFOLGE      = /[^ \n<>]+/
NZ                = /\n/
LEERZEILE         = /\n[ \t]*(?=\n)/~
JAHRESZAHL        = /\d\d\d\d/
ENDE              = !/./
L                 = /[ \t]+/~           # signifikanter leerraum