BibTeX.ebnf

# BibTeX-Grammar


#######################################################################
#
#  EBNF-Directives
#
######################################################################

@ whitespace  = /\s*/
@ ignorecase  = True
@ comment     = //


#######################################################################
#
#  Bib-file Structure and Components
#
#######################################################################

bibliography = { preamble | comment | entry }

preamble      = "@Preamble{" /"/ pre_code /"/~ §"}"
pre_code      = { /[^"%]+/ | /%.*\n/ }

comment       = "@Comment{" text §"}"

entry         = /@/ type "{" key { "," field §"=" content } [","] §"}"
type          = WORD
key           = NO_BLANK_STRING
field         = WORD
content       = "{" text "}" | plain_content

plain_content = COMMA_TERMINATED_STRING
text          = { CONTENT_STRING | "{" text "}" }


#######################################################################
#
#  Regular Expressions
#
#######################################################################

WORD          = /\w+/~
NO_BLANK_STRING         = /[^ \t\n,%]+/~
COMMA_TERMINATED_STRING = { /[^,%]+/ | /(?=%)/~ }
CONTENT_STRING = { /[^{}%]+/ | /(?=%)/~ }+

EOF           =  !/./